SAP TabStrip(Report Program) 정리

TabStrip 정리

---

# 다음은 Report Program에서 사용하는 TabStrip을 알아보려고 한다.

물론 Report Program에서 사용되는 TabStrip는 여러 가지가 있지만 감자는 더 편한 방법을 사용하겠다. 

 

 

Report Program에서 TabStrip을 사용하기 위해서는 

서브 스크린을 설정해야 한다.

또한 

USER-COMMAND를 설정해주어야 한다.

 

시작해 보자.

 

 

 

# 1단계 - SubScreen 정의( TOP )

---

SELECTION-SCREEN BEGIN OF SCREEN 101 aS SUBSCREEN.

  PARAMETERS:
    PA_ID TYPE SFLIGHT-CARRID,
    PA_CON TYPE SFLIGHT-CONNID.

SELECTION-SCREEN END OF SCREEN 101.


SELECTION-SCREEN BEGIN OF SCREEN 102 aS SUBSCREEN.

  SELECT-OPTIONS:
    SO_DATE FOR SFLIGHT-FLDATE.

SELECTION-SCREEN END OF SCREEN 102.

# 사용자가 원하는  Parameters , Select-Options 설정을 해준 뒤에 AS SUBSCREEN으로 정의를 해준다.

 

# 여기서 설정한 서브스크린 ( 101, 102 )을 기억해 보자.

 

 

# 2단계 - 탭  블록 설정 ( TOP )

---

SELECTION-SCREEN: BEGIN OF TABBED BLOCK MYTAB FOR 5 LINES,
  TAB (20) TABNAME1 USER-COMMAND TAB1,
  TAB (20) TABNAME2 USER-COMMAND TAB2,
                  END OF BLOCK MYTAB.

1. 사용자가 원하는 탭 블록 라인의 수를 지정해 주면 된다. 

1-1. MYTAB은 TabStrip Control의 이름이기 때문에 설정을 잘해주자.

 

2. TAB (20) -> 탭의 이름을 넣을 수 있는 자릿수이다. 

 

3. ( TABNAME1, TABNAME2 )는 탭의 이름을 설정해 주는 구문이다. 

 

4. ( TAB1, TAB2 )는 사용자가 클릭할 때 USER-COMMAND에 값이 나오는 값이다.

     # 예를 들어 tab1을 클릭했다면

      SY-UCOMM = TAB1.

 

`

# 3단계 - TAB 이름 설정( INITIALIZATION )

---

# 해당하는 탭의 이름과 기본적인 "MYTAB" 값들을 위해서 설정한 값들을 다음과 같이 넣어보자.

  TABNAME1 = 'Ariline ID'.
  TABNAME2 = 'Flight Date'.
  MYTAB-PROG = SY-REPID.
  MYTAB-DYNNR = 101.
  MYTAB-ACTIVETAB = 'TAB1'.

 

 

# 4단계 - 이벤트에 따른 로직 설정( AT SELECTION-SCRREN )

---

# Report Program 1000일 때, 위에서 설정했던 User Command을 통해서 ( 101, 102 )을 동적으로 변경하는 로직을 짜보자. 

AT SELECTION-SCREEN.
  CASE SY-DYNNR.
    WHEN 1000.
      CASE SY-UCOMM.
        WHEN 'TAB1'.
          mytab-dynnr = 101.
        WHEN 'TAB2'.
          mytab-dynnr = 102.
      ENDCASE.
  ENDCASE.

 

# 5단계 - TabStrip에 따라서 Execute(F8)을 눌렀을 때, 변경되는 로직 설정

( START-OF-SELECTION )

---

  CASE MYTAB-ACTIVETAB.
    WHEN 'TAB1'.
      WRITE:
        PA_ID,
        PA_CON.
    WHEN 'TAB2'.
      WRITE:
        SO_DATE-LOW,
        SO_DATE-HIGH.
  ENDCASE.

 

 

실행 결과

---

TAB1( Airline ID )

 

TAB2( Flight Date ) 

 

 

---

Module Pool에서 사용하는 TabStrip을 알고 싶으면 밑에 링크를 확인하면 된다.

https://potato98.tistory.com/19

SAP Tabstrip 정리

---

 

 

도움이 되셨으면 하단에 있는 광고 한번씩 눌러주세유!!